Muon decay matrix element

<< "dirac/Tracer.m"

VectorDimension[4]

Spur[1]

muontensor = 
      G[le, pmu + 
            mmu U] ** ((1/2) (G[le, U] + G[le, G5] ** G[le, smu])) ** 
        G[le, {alpha}] ** (G[le, U] - G[le, G5]) ** G[le, pnumu] ** 
        G[le, {mu}] ** (G[le, U] - G[le, G5])

mutensor = muontensor /. le -> 1

electrontensor = 
      G[le, pe + 
            me U] ** ((1/2) (G[le, U] + G[le, G5] ** G[le, se])) ** 
        G[le, {mu}] ** (G[le, U] - G[le, G5]) ** G[le, pnue] ** 
        G[le, {alpha}] ** (G[le, U] - G[le, G5])

etensor = Simplify[electrontensor /. le -> 1]

msq = 
      Simplify[(1/2) (Gf^2) ContractEpsGamma[etensor mutensor]]

Rewrite al a Cummins:

msqc = 
      32 Gf^2 (S[pmu, {alpha}]  -  
            mmu S[ smu, {alpha}]) *
(S[
              pe, {beta}]  -  
            me S[ se, {beta}]) (Pi/6 q . 
                q S[{alpha}, { beta}]  +  
            Pi/3 S[q, {alpha}] S[q, {beta}])

msqc1  =  Simplify[ContractEpsGamma[msqc]]

Vectors:

ppmu = {mmu, 0, 0, 0}

ppe  =  {e,  p sint, 0, p cost}

qq  =  ppmu - ppe

ssmu  =  {0, 0, 0, 1}

sehat  =  {0, sex, sey, sez}

metric  =  {{1, 0, 0, 0}, {0, -1, 0, 0}, {0, 0, -1, 0}, {0, 
          0, 0, -1}}

sse  =  
      sehat  - 
        ppe . metric . 
            sehat ppe/(me (ppe[[1]] + me))

msqc2  =  
      Simplify[(msqc1 /. {q . q -> qq . metric . qq, 
                se . smu -> sse . metric . ssmu, 
                pmu . q -> ppmu . metric . qq, 
                q . smu -> qq . metric . ssmu, 
                pe . pmu -> ppe . metric . ppmu, 
                pe . q -> ppe . metric . qq, 
                pe . smu -> ppe . metric . ssmu, 
                pmu . se -> ppmu . metric . sse,  
                q . se -> qq . metric . sse}) /. {sint^2 -> 
              1 - cost^2, p^2 -> e^2 - me^2}]

msqc3 = 
      Simplify[msqc2 /. {me -> 0, p -> e}] /. 
        sint^2 -> 1 - cost^2

Substitute for the helicity of the electron (n.s):

msqc4 = 
      Simplify[msqc3 /. {sex -> (n . s  -  cost sez)/sint, 
            e ->  ep mmu/2}]

Phase space factor (with integration over ep instead of e):

phasespace  =  1/16 /(2 Pi)^5 ep/
          mmu (mmu/2)^2

dlambda  =  msqc4*phasespace

To the extent the electron is massless, the spin must be opposite the direction of motion.  The normalized energy distribution is:

enorm[ep_]  =  2 ep^2 (3  -  2 ep)

Integrate[enorm[e], {e, 0, 1}]

plot1  = Plot[enorm[e], {e, 0, 1}]

This distribution is slightly different than "phase space" which would be:

plot2  =  Plot[2 e, {e, 0, 1}]

Show[plot1, plot2]

asym[ep_, cost_]  =  (1 + (1 - 2 ep)/(3 - 2 ep) cost)/
        2

Integrate[asym[e, z], {z, -1, 1}]

aparam  = 
      Simplify[ 
        Integrate[asym[e, z], {z, 0, 1}] - 
          Integrate[asym[e, z], {z, -1, 0}]]

Plot[aparam, {e, 0, 1}]