Example18.5 of pages 190-191

The version number of Mathematica used to evaluate this notebook:

$VersionNumber

We see that  (18.26) on page 190 has the following coefficients

c[0, 0][z_] = 1

c[0, 1][z_] = -9/z

c[0, 2][z_] = 144/(5  z^2)

c[0, 3][z_] = - 156/(5  z^3)

c[1, 1][z_] = 396/(5  z^2)

c[1, 2][z_] = -1233/(5  z^3)

c[1, 3][z_] = 261/z^4

c[2, 2][z_] = 747/z^4

c[2, 3][z_] = -783/z^5

c[3, 3][z_] = 819/z^6

We also have

c[j_, i_][z_] := c[i, j][z] /; j > i

and

M = Table[c[i, j][z], {i, 0, 3}, {j, 0, 3}];

M // MatrixForm

Thus, for the determinant of the left member of (18.26), we obtain

Det[M]

We note that the left member of (18.26) is given by

Q3[z_] = 
      Sum[c[i, j][z]*D[y[z], {z, 3 - i}]*D[y[z], {z, 3 - j}], {i, 0, 3}, {
          j, 0, 3}]

We use (18.5), (18.6), (18.7), and (18.8) to obtain

B[i_, j_][z_] := 
      Factor[c[i, j][z] - c[0, i][z]*c[0, j][z]] /; 
        (1 <= i <= 3 && 1 <= j <= 3)

B[i_, 4][z_] := 0

B[4, j_][z_] := 0

A[i_, j_][z_] := 
      Factor[D[B[i, j][z], z] + B[i + 1, j][z] + B[i, j + 1][z]]

and

theta[r_, s_, i_, j_][z_] := 
      Simplify[B[r, s][z]*
            (A[i, j][z] - B[1, i][z]*c[0, j][z] - 
                B[1, j][z]*c[0, i][z]) - 
          B[i, j][z]*
            (A[r, s][z] - B[1, r][z]*c[0, s][z] - 
                B[1, s][z]*c[0, r][z])]

Since we have

B[1, 1][z]

we apply Theorem 18.1 on page 186 with

p = 1

and

q = 1

To see that (18.9) is satisfied, we find that

Do[Print["theta[", p, ", ", q, ", ", i, ", ", j, 
        "][z] = ", theta[p, q, i, j][z]], {i, 1, 3}, {j, i, 3}]

Thus, the hypotheses of Theorem 18.1 are satisfied and we apply (18.10) to obtain

lam = 
      Factor[(
            B[1, p][z]*c[0, q][z] + B[1, q][z]*c[0, p][z] - 
              A[p, q][z])/B[p, q][z]]

With respect to this  lam  and the earlier  Q3[z]  given by

Q3[z]

we obtain the following factorization that correspondss to (18.11).

prod = Factor[Q3'[z] + lam*Q3[z]]

For (18.27) and (18.28), we see that

L3 = 2*Expand[(1/(5  z^3))*prod[[3]]]

and

L4 = prod/L3 // Factor // Expand

Wre find that

DSolve[L3 == 0, y[z], z]

t[z_] = 
      K1*z^((20 - Sqrt[205])/5) + K2*z^4 + 
        K3*z^((20 + Sqrt[205])/5)

FullSimplify[
      L3 /. {y[z] -> t[z], y'[z] -> t'[z], 
          y''[z] -> t''[z], 
          y'''[z] -> t'''[z]}]

FullSimplify[
      Q3[z] /. {y[z] -> t[z], y'[z] -> t'[z], 
          y''[z] -> t''[z], 
          y'''[z] -> t'''[z]}]

Thus, the solutions of  L3 = 0  that are also solutions of  Q3 = 0  are given by (18.29) on page 191.  We also have

sol = DSolve[L4 == 0, y[z], z]

y0[z_] := K1*z + K2*z^3 + K3*z^5 + K4*z^7

FullSimplify[
      L4  /. {y[z] -> y0[z], y'[z] -> y0'[z], 
          y''[z] -> y0''[z], 
          y'''[z] -> y0'''[z], 
          y''''[z] -> y0''''[z]}]

FullSimplify[
      Q3[z] /. {y[z] -> y0[z], y'[z] -> y0'[z], 
          y''[z] -> y0''[z], 
          y'''[z] -> y0'''[z]}]

Thus, the solutions of  L4 = 0  that are also solutions of  Q3 = 0  are given by (18.31) on page 191.

This concludes Example 18.5 on pages 190--191.