Proof of Proposition 19.12

The version number of Mathematica used to evaluate this notebook:

$VersionNumber

The Wronskian of  (Subscript[u, 1])(z),  (Subscript[u, 2])(z),  (Subscript[u, 3])(z) is given by

W=Det[(({{u0[z], u1[z], u2[z]}, {u0'[z], u1'[z], u2'[z]}, {u0''[z], u1''[z], u2''[z]}}))];

We introduce

W0=Det[(({{y[z], u1[z], u2[z]}, {y'[z], u1'[z], u2'[z]}, {y''[z], u1''[z], u2''[z]}}))];

W1=Det[(({{u0[z], y[z], u2[z]}, {u0'[z], y'[z], u2'[z]}, {u0''[z], y''[z], u2''[z]}}))];

and

W2=Det[(({{u0[z], u1[z], y[z]}, {u0'[z], u1'[z], y'[z]}, {u0''[z], u1''[z], y''[z]}}))];

in order to solve for (Subscript[K, 1]),  (Subscript[K, 2]),  (Subscript[K, 3 ])in the relations 
    (Subscript[K, 0]) (Subscript[u, 0])(z)   +  (Subscript[K, 1]) (Subscript[u, 1])(z)  +  (Subscript[K, 2]) (Subscript[u, 2])(z) =  y(z)
    (Subscript[K, 0]) (Subscript[u, 0])' (z)  + (Subscript[K, 1]) (Subscript[u, 1])' (z) + (Subscript[K, 2]) (Subscript[u, 2])'(z)  =  y'(z)
    (Subscript[K, 0]) (Subscript[u, 0])'' (z) + (Subscript[K, 1]) (Subscript[u, 1])'' (z) + (Subscript[K, 3]) (Subscript[u, 2])''(z) =  y''(z)
as  (Subscript[K, 0 ])= (Subscript[W, 0])/W,  (Subscript[K, 1])= (Subscript[W, 1])/W, (Subscript[K, 2])= (Subscript[W, 2])/W.

For the situation where   y(z) ≡ (C^2)(Subscript[u, 1])(z) + CK (Subscript[u, 2])(z) +(K^2)(Subscript[u, 3])(z) and therefore   (Subscript[K, 0 ]) ≡   (C^2),  (Subscript[K, 1]) ≡ C K,  (Subscript[K, 2]) ≡   (K^2) with   ((((Subscript[K, 1])))^2) -  (Subscript[K, 0]) (Subscript[K, 2]) ≡  0, we see that y(z), y'(z), y''(z)  must satisfy    
      ((((Subscript[W, 1])))^2)  -  (Subscript[W, 0]) (Subscript[W, 2 ])  ≡  0.

Here, for July04   we replaced      (Subscript[W, 1]) (Subscript[W, 3 ])- ((((Subscript[W, 2])))^2)= 0  of the previous notebook for 
March04 with ((((Subscript[W, 1])))^2) -  (Subscript[W, 0]) (Subscript[W, 2 ])=0

eq1 = (W1)^2  -  W0*W2 // Expand;

As a check, we set

y0[z_] = C^2*u0[z] + C*K*u1[z] + K^2*u2[z]

and obtain

eq1 /. {y[z] -> y0[z], y'[z] -> y0'[z], 
          y''[z] -> y0''[z]} // Simplify

The second-order differential equation  eq1 = 0  yields (19.64) on page 204.  Its coefficients are given by

a = Factor[Coefficient[eq1, y''[z]*y''[z]]]

Expand[
      (u0[z]*u2'[z] - u0'[z]*u2[z])^2  - 
        (u0[z]*u1'[z] - u0'[z]*u1[z])*
          (u1[z]*u2'[z] - u1'[z]*u2[z]) - a]

(The preceding gives (19.65) on page 204.)

b = Coefficient[eq1, y''[z]*y'[z]]

b + D[a, z] // Expand

c = Coefficient[eq1, y''[z]*y[z]]

D[a, z]

d = Coefficient[eq1, y'[z]*y'[z]]

e = Coefficient[eq1, y'[z]*y[z]]

and

f = Coefficient[eq1, y[z]*y[z]]

To obtain (19.66), we divide (19.64) by  a  and find that the modified coefficients are given by

c00[z_] = 1

c01[z_] = b/(2*a)

c02[z_] = c/(2*a)

c11[z_] = d/a

c12[z_] = e/(2*a)

c22[z_] = f/a

Of course, we have

c10[z_] = c01[z];  c20[z_] = c02[z];  c21[z_] = c12[z];

Thus, (19.66) is given by

Q2[z_] = 
      c00[z]*y''[z]*y''[z] + 
        2  c01[z]*y''[z]*y'[z] + 2  c02[z]*y''[z]*y[z] + 
        c11[z]*y'[z]*y'[z] + 2  c12[z]*y'[z]*y[z] + 
        c22[z]*y[z]*y[z];

As a further check that (Subscript[y, 0])(z)  is a solution of  Q2 = 0, we have

Q2[z] /. {y[z] -> y0[z], y'[z] -> y0'[z], 
          y''[z] -> y0''[z]} // Simplify

Now, through a series of computations, MATHEMATICA enables us to derive the formulas at the middle of page 204 as follows.

B11[z_] = c11[z] - c01[z]*c01[z] // Together;

G = Numerator[B11[z]];

Factor[G]

Factor[G/W^2]

Expand[( 4*u0[z]*u2[z] - (u1[z])^2 )*W^2 - G]

H = Denominator[ B11[z] ]

4*a^2

H - (4*a^2) // Expand

B11[z] - (4*u0[z]*u2[z] - (u1[z])^2)*W^2/(4*a^2) // Together

(The preceding gives the formula   (Subscript[B, 1, 1])(z)  ≡  ((-Δ(z) (((W(z) ))^2))/(4 
                (((a(z)))^2)))  as the first of the displayed in the last two lines of page 204.)

B12[z_] = c12[z] - c01[z]*c02[z] // Together;

B22[z_] = c22[z] - c02[z]*c02[z] // Together ;

D2[z_] = B11[z]*B22[z] - (B12[z])^2 // Together;

Factor[D2[z]]

Factor[a^3* D2[z]/(W)^4]

D2[z] + W^4/(4*a^3) // Together

(The preceding establishes the second of the five formulas in the last two lines of page 204.)

theta[1, 1, 1, 2][z_] = 
      B11[z]*B22[z] - 2*(B12[z])^2 + c01[z]*B11[z]*B12[z] - 
          c02[z]*(B11[z])^2 + B11[z]*B12'[z] - B12[z]*B11'[z] 
         // Together

(The preceding gives the third of the five formulas.)

theta[1, 1, 2, 2][z_] = 
      B11[z]*B22'[z] - B11'[z]*B22[z] - 2*B12[z]*B22[z] + 
          2*c01[z]*B11[z]*B22[z] - 2*c02[z]*B11[z]*B12[z] // Together

The preceding gives the fourth of the five formulas.  Consequently, (19.5) is satisfied and Proposition 19.1 is applicable to (19.66).   We use (18.10) to obtain

lamb[z_] = 
      2*c01[z] - (B11'[z] + 2*B12[z])/B11[z] // Together;

num = Numerator[lamb[z]];

den = Denominator[lamb[z]];

den - a*W // Expand

expr1 = B11'[z] + 2*B12[z] // Factor;

expr2 =  
      -2*a^3* expr1/(W*((u1[z])^2 - 4*u0[z]*u2[z])) // Factor

expr3 = expr2 - a*D[W, z] // Factor

expr4 = expr3/W

D[a, z]

expr5 = expr4 + D[a, z]

lamb[z] - 2*(c01[z] + (D[a, z]*W - a*D[W, z])/(a*W)) // 
      Together

lamb[z] - 2*(c01[z] + D[a, z]/a - D[W, z]/W ) // Together

(The preceding yields the formula for  λ(z)  at the bottom of page 204.)

We recall that the left member   Q2[z]  of (19.66) is given by

Q2[z];

For it, we set

L2 = 
      Collect[D[ Q2[z], y''[z] ], {y[z], y'[z], 
          y''[z]}];

and

L3=Collect[(1/W)*Det[(({{u0[z], u1[z], u2[z], y[z]}, {u0'[z], u1'[z], u2'[z], y'[z]}, {u0''[z], u1''[z], u2''[z], y''[z]}, {u0'''[z], u1'''[z], u2'''[z], y'''[z]}}))],
		{y[z],  y'[z], y''[z], y'''[z]}, Factor ]

FullSimplify[Q2'[z] + lamb[z]*Q2[z] - L2*L3]

It establishes the remaining identity for (19.67).

For the middle of page 205

y[1][z_ ] = u0[z];

y[2][z_] = u2[z];

y[3][z_] = u0[z] + u1[z] + u2[z];

y[4][z_] = 4  u0[z] + 2  u1[z] + u2[z];

y[5][z_] = u0[z] + 2  u1[z] + 4  u2[z];

rowForY[i_] = {y[i]''[z]*y[i]'[z], 
        y[i]''[z]*y[i][z], y[i]'[z]^2, 
        y[i]'[z]*y[i][z], y[i][z]^2};

Y = {rowForY[1], rowForY[2], rowForY[3], rowForY[4], rowForY[5]};

Y // MatrixForm

Det[Y] // Factor

Expand[Det[Y] + 12*a*W^2]

For Proposition 19.3, we specialize the preceding formulas for (19.65) with the following assumed values for (Subscript[u, 0])(z),  (Subscript[u, 1])(z),  and  (Subscript[u, 2])(z), .

u0[z_] = sigma[z]^2

u2[z_] = tau[z]^2

u1[z_] = 2*sigma[z]*tau[z]

Factor[W]

Of course, the Wronskian of     { sigma[z], tau[z] }  is

Det[{{sigma[z], tau[z]}, {sigma'[z], tau'[z]}}]

a // Expand

b // Expand

Factor[c]

Factor[d]

Expand[c + 2  d]

R3[z_] = 
      y''[z]*y[z] - (1/2)*y'[z]^2 + alpha[z]*y'[z]*y[z] + 
        2*bet[z]*y[z]^2

Collect[
      ( R3'[z] + 2*alpha[z]*R3[z])/y[z], {y[z], y'[z], 
        y''[z]}]

The preceding gives (19.70),  (19.71), and (19.72).  For (19.73), we obtain

R3[z] /. {y[z] -> t[z]^2, y'[z] -> D[ t[z]^2, z], 
          y''[z] -> D[t[z]^2, {z, 2}]} // Factor

Finally, for (19.78) and (19.79), we have

Rn = 
      y''[z]*y[z] + ((2 - n)/(n - 1))*y'[z]^2 + 
        alpha[z]*y'[z]*y[z] + (n - 1)*bet[z]*y[z]^2

and

Rn /. { y[z] -> u[z]^(n - 1), 
          y'[z] -> D[ u[z]^(n - 1), z], 
          y''[z] -> D[ u[z]^(n - 1), {z, 2}]} // FullSimplify