Example 19.8 of page 198

The version number of Mathematica used to evaluate this notebook:

$VersionNumber

We see that  (19.27) on page 198 has the following coefficients

c[0, 0][z_] = 1

c[0, 1][z_] = - (5  z^2 + 1)/(z (z^2 + 1))

c[0, 2][z_] = 
      (23  z^4 - 2  z^2 - 1)/(3  z^2 (z^2 + 1)^2)

c[1, 1][z_] = 
      4 (19  z^4 + 8  z^2 + 1)/(3  z^2 (z^2 + 1)^2)

c[1, 2][z_] = 
      -2 (59  z^4 + 10  z^2 - 1)/(3  z (z^2 + 1)^3)

c[2, 2][z_] = 
      4 (46  z^6 - 3  z^4 + 1)/(3  z^2 (z^2 + 1)^4)

We also have

c[j_, i_][z_] := c[i, j][z] /; j > i

and

M = Table[c[i, j][z], {i, 0, 2}, {j, 0, 2}];

M // MatrixForm

Thus, for the determinant of the left member of (19.27), we obtain

Det[M] // Factor

We note that the left member of (19.27) is given by

Q2[z_] = 
      Sum[ c[i, j][z]*D[y[z], {z, 2 - i}]*D[y[z], {z, 2 - j}], {i, 0, 
          2}, {j, 0, 2}]

We use (18.5), (18.6), (18.7), and (18.8) to obtain

B[i_, j_][z_] := 
      Factor[c[i, j][z] - c[0, i][z]*c[0, j][z]] /; 
        (1 <= i <= 2 && 1 <= j <= 2)

B[i_, 3][z_] := 0

B[3, j_][z_] := 0

A[i_, j_][z_] := 
      Factor[D[B[i, j][z], z] + B[i + 1, j][z] + B[i, j + 1][z]]

and

theta[r_, s_, i_, j_][z_] := 
      Simplify[B[r, s][z]*
            (A[i, j][z] - B[1, i][z]*c[0, j][z] - 
                B[1, j][z]*c[0, i][z]) - 
          B[i, j][z]*
            (A[r, s][z] - B[1, r][z]*c[0, s][z] - 
                B[1, s][z]*c[0, r][z])]

Since we have

B[1, 1][z]

we apply Theorem 18.1 on page 186 with

p = 1

and

q = 1

(Proposition 19.1 on page 194 could also be used.)  We have

B[1, 2][z]

B[2, 2][z]

and

D2[z_] = B[1, 1][z]*B[2, 2][z] - B[1, 2][z]^2 // Factor

The computation

theta[1, 1, 1, 2][z]

and

theta[1, 1, 2, 2][z]

show that the hypotheses of Theorem 18.1 are satisfied.  The theorem yields

lam = 
      Factor[(
            B[1, p][z]*c[0, q][z] + B[1, q][z]*c[0, p][z] - 
              A[p, q][z])/B[p, q][z]]

prod = Factor[Q2'[z] + lam*Q2[z]]

S2 = 
      Collect[prod[[4]]/(3  z^2 (z^2 + 1)^2), {y''[z], 
          y'[z], y[z]}, Factor]

L3 = 
      Collect[prod[[5]]/(z^2 + 1)^3 , {y'''[z], 
          y''[z], y'[z], y[z]}, Factor]

crazy = DSolve[L3 == 0, y[z], z] // FullSimplify

Version 3.0 is unable to evaluate the preceeding input.

If[ $VersionNumber  >=  4.1,  u[z_]  =  y[z] /. crazy[[1]]]

If[$VersionNumber >= 4.1, 
      L3 /. {y[z] -> u[z], y'[z] -> u'[z], 
            y''[z] -> u''[z], 
            y'''[z] -> u'''[z]} // FullSimplify]

Thus,  DSolve does not give a simple expression for the solutions of  L3 == 0.  However, in conjunction with Theorem 19.7 on page 197, the solutions of  L3 ==0  can be obtained with  DSolve  as follows.

The expression

-D2[z]/B[1, 1][z]^2

shows that we can define τ(z) for Theorem 19.7 as

tau[z_] = 2/(Sqrt[3] z)

Then, for (19.21), we have

eqn = 
      eta'[z] + 
          ((B[1, 1]'[z] + B[1, 2][z])/B[1, 1][z] - tau[z])
               eta[z] == 0

sol = DSolve[eqn, eta[z], z] // FullSimplify

eta[z_]  =  eta[z]  /.  sol[[1]]  /.  C[1] -> 1

As a check, we see that

Simplify[ 
      eta'[z] + 
        ((B[1, 1]'[z] + B[1, 2][z])/B[1, 1][z] - tau[z]) 
          eta[z] ]

For the left member of (19.22), we have

expr = 
      w''[z] + 
        ( tau[z] - B[1, 1]'[z]/(2  B[1, 1][z])) w'[z] + 
        (B[1, 1][z]/4) w[z]

The solutions of (19.22) are

sol2 = DSolve[expr == 0, w[z], z]

We set

phi[z_] = 
      w[z] /. sol2[[1]] /. C[1] -> 1 /. C[2] -> 0 // Simplify

and

psi[z_] = 
      w[z] /. sol2[[1]] /. C[1] -> 0 /. C[2] -> 1 // Simplify

and observe that

Together[{ -1/2 - 1/Sqrt[3], 1/2 - 1/Sqrt[3]}]

As a check that

v[z_] = C1*phi[z] + C2*psi[z]

is a solution of   expr == 0, we see find that

expr
         /. {w[z] -> v[z], w'[z] -> v'[z], 
          w''[z] -> v''[z]} // Simplify

Now, (19.23) yields the nonsingular solutions of  (19.27) as

y1[z_] = 
      B[1, 1][z]*eta[z] (C1*phi[z] + C2*psi[z])^2 + 
          4*eta[z] (C1*phi'[z] + C2*psi'[z])^2 // FullSimplify

Here, for  ChalkleyJan05.dvi , the definitions of  (Subscript[h, 0])  and  (Subscript[k, 0]) have been simplified.  Now we set

h0  =  2 Sqrt[ 2/3  +  1/Sqrt[3] ]

and

k0  =  2 Sqrt[ 2/3  -  1/Sqrt[3] ]

In comparison with the former definitions, we note that

FullSimplify[ 
      h0  -  (2/3) 
          (3  Sqrt[2 - Sqrt[3]] + 2  Sqrt[3 (2 - Sqrt[3])]) ]

and

FullSimplify[ k0 - 2*Sqrt[(1/3) (2 - Sqrt[3])] ]

With these values, the same simplification occurs that expresses the nonsingular solutions of (19.27) in the simpler form

y2[z_] = y1[z] /. {C1 -> C/h0, C2 -> K/k0} // Simplify

As a check, we obtain

Q2[z] /. { y[z] -> y1[z], y'[z] -> y1'[z], 
          y''[z] -> y1''[z]} // Simplify

and

Q2[z] /. { y[z] -> y2[z], y'[z] -> y2'[z], 
          y''[z] -> y2''[z]} // Simplify

In terms of (19.26), we find that the singular solutions of (19.27) are given by

DSolve[
        y'[z] + (B[1, 2][z]/B[1, 1][z] - tau[z]) y[z] == 0, 
        y[z], z] // Simplify

and

DSolve[
        y'[z] + (B[1, 2][z]/B[1, 1][z] + tau[z]) y[z] == 0, 
        y[z], z] // Simplify