Here, we check the statements made for Example 15.7 on page 162.

The version number of Mathematica used to evaluate this notebook:

$VersionNumber

m = 3

c[0, 0][z_] = 1

c[j_, i_][z_] := c[i, j][z] /; j > i

Formula (2.5) on page 23 gives

cStar[i_, j_][z_] := 
      Sum[Binomial[3 - mu, i - mu]*Binomial[3 - nu, j - nu]*
          (D[rho[z], {z, i - mu}]*D[rho[z], {z, j - nu}]/(rho[z])^2)*
          c[mu, nu][z], {mu, 0, i}, {nu, 0, j}]

cStar[1, 1][z]

cStar[0, 1][z]

cStar[1, 1][z]  -  cStar[0, 1][z]^2 // Expand

We use (3.1) and (3.2) on page 29 to obtain

alpha[0, j_] = 1

alpha[1, j_]  :=  
      Sum[ D[ alpha[0, k], zet] - 
          (0 + k) (f''[zet]/f'[zet]) alpha[0, k], {k, 1, 
          j}]

alpha[2, j_]  :=  
      Sum[ D[ alpha[1, k], zet] - 
          (1 + k) (f''[zet]/f'[zet]) alpha[1, k], {k, 1, 
          j}]

and

alpha[3, j_]  :=  
      Sum[ D[ alpha[2, k], zet] - 
          (2 + k) (f''[zet]/f'[zet]) alpha[2, k], {k, 1, 
          j}]

Using  (3.19) on page 34 as a check, we have

alp[1, j_]  =  
      -Binomial[j + 1, 2]*(f''[zet]/f'[zet])

and

\(\(Do[
      Print["alpha[1, ", j, "] - alp[1, ", j, "] = ", \ 
			
        Expand[\ alpha[1, j]\  - \ alp[1, j]\ ]\ ], {j, 0, 9}]\ \)\)

Using (3.24) on page 34 as a check, we have

alp[2, j_]  =  
      -Binomial[j + 2, 3]*(f'''[zet]/f'[zet])  +  
        3*Binomial[j + 3, 4]*(f''[zet]/f'[zet])^2

and

\(\(Do[
      Print["alpha[2, ", j, "] - alp[2, ", j, "] = ", \ 
			
        Expand[\ alpha[2, j]\  - \ alp[2, j]\ ]\ ], {j, 0, 9}]\ \)\)

For   0 ≤  i , j  ≤ 3  and  m = 3,  formula (3.9) on page 30 yields

cStarStar[i_, j_][zet_]  :=  
      Sum[ (f'[zet])^(mu + nu)*alpha[i - mu, 3 - i]*
          alpha[j - nu, 3 - j]*c[mu, nu][f[zet]], {mu, 0, i}, {nu, 0, j}]

cStarStar[1, 1][zet]

cStarStar[0, 1][zet]

cStarStar[1, 1][zet] - cStarStar[0, 1][zet]^2 // Factor

B[i_, j_][z_] := c[i, j][z] - c[0, i][z]*c[0, j][z]

BStar[i_, j_][z_] := 
      cStar[i, j][z] - cStar[0, i][z]*cStar[0, j][z]

BStarStar[i_, j_][zet_] := 
      cStarStar[i, j][zet] - 
        cStarStar[0, i][zet]*cStarStar[0, j][zet]

delta[i_, j_, k_][z_] := 
      B[i, j][z]*B[k, k][z] - B[i, k][z]*B[j, k][z]

deltaStar[i_, j_, k_][z_] := 
      BStar[i, j][z]*BStar[k, k][z] - 
        BStar[i, k][z]*BStar[j, k][z]

deltaStarStar[i_, j_, k_][zet_] := 
      BStarStar[i, j][zet]*BStarStar[k, k][zet] - 
        BStarStar[i, k][zet]*BStarStar[j, k][zet]

Together[BStar[1, 1][z] - B[1, 1][z]]

Together[deltaStar[1, 1, 2][z] - delta[1, 1, 2][z]]

Together[
      deltaStarStar[1, 1, 2][zet] - 
        (f'[zet])^6*delta[1, 1, 2][f[zet]]]

Thus,  Δ[1, 1, 2]  is a relative invariant.

TrueQ[Together[deltaStar[1, 1, 3][z] - delta[1, 1, 3][z]] == 0]

Together[
      deltaStarStar[1, 1, 3][zet] - 
        (f'[zet])^8*delta[1, 1, 3][f[zet]]]

Thus,  Δ[1, 1, 3]  is merely a semi-invariant of the second kind.

TrueQ[
      Together[deltaStar[2, 3, 1][z] - delta[2, 3, 1][z] ] == 0]

Together[
      deltaStarStar[2, 3, 1][zet] - 
        (f'[zet])^7*delta[2, 3, 1][f[zet]]]

Thus,  Δ[2, 3, 1]  is merely a semi-invariant of the second kind.

TrueQ[
      Together[deltaStar[2, 2, 3][z] - delta[2, 2, 3][z] ] == 0]

TrueQ[
      Together[deltaStarStar[2, 2, 3][zet] - 
            (f'[zet])^10*delta[2, 2, 3][f[zet]]] == 0]

Thus,  Δ[2, 2, 3]  is not a semi-invariant of either kind.

TrueQ[
      Together[deltaStar[1, 2, 3][z] - delta[1, 2, 3][z] ] == 0]

TrueQ[
      Together[deltaStarStar[1, 2, 3][zet] - 
            (f'[zet])^9*delta[1, 2, 3][f[zet]]] == 0]

Thus,  Δ[1, 2, 3]  is not a semi-invariant of either kind.

TrueQ[
      Together[deltaStar[1, 3, 2][z] - delta[1, 3, 2][z] ] == 0]

TrueQ[
      Together[deltaStarStar[1, 3, 2][zet] - 
            (f'[zet])^8*delta[1, 3, 2][f[zet]]] == 0]

Thus,  Δ[1, 3, 2]  is not a semi-invariant of either kind.