Complete details for Section 12.2 
based on Chapter 13.1 and 13.3
(with m = 5 and n = 1)

Input from Section 13.1

$Version

m=5;

u[s_,p1_,r_]:=Floor[(1/(p1+r))*(s-Sum[(p1+k)*e[s,p1,k],{k,r+1,s-p1}]-Sum[(i1+k)*e[s,i1,k],{i1,p1+1,m},{k,0,s-i1}])]

nM[s_]:=Module[{counter,seq},counter=0;
seq=Apply[Sequence,Reverse[Flatten[Table[{e[s,i1,k],0,u[s,i1,k]},{i1,1,m},{k,0,s-i1}],1]]];
Do[If[(Sum[(i1+k)*e[s,i1,k],{i1,1,m},{k,0,s-i1}])==s,(counter=counter+1;
monM[s,counter]=Product[D[w[i1][z],{z,k}]^e[s,i1,k],{i1,1,m},{k,0,s-i1}]),counter=counter],Evaluate[seq]];counter]

printM[s_]:=Do[Print["monM[",s,",",j,"] = ",monM[s,j]],{j,1,nM[s]}]

wPolynomial[s_]:=Sum[x[s,j]*monM[s,j],{j,1,nM[s]}]

sub[s_]:=Flatten[Table[D[w[i1][z],{z,k}]->D[c[i1][z],{z,k}],{i1,1,m},{k,0,s-i1}]]

cPoly[s_]:=wPolynomial[s]/.sub[s]

c[0][z_]=1;

cOneStar[i1_][z_]:=Sum[Binomial[m-j1,i1-j1]*(D[rho[z],{z,i1-j1}]/rho[z])*c[j1][z],{j1,0,i1}]

sub1[s_]:=Flatten[Table[D[w[i1][z],{z,k}]->D[cOneStar[i1][z],{z,k}],{i1,1,m},{k,0,s-i1}]]

cOneStarPoly[s_]:=wPolynomial[s]/.sub1[s]

alpha[0,j_][zet_]=1;

alpha[i_,j_][zet_]:=Sum[D[alpha[i-1,k][zet],zet]-(i-1+k)(f''[zet]/f'[zet])alpha[i-1,k][zet],{k,1,j}]/;i≥1

cTwoStar[i1_][zet_]:=Sum[f'[zet]^mu*alpha[i1-mu,m-i1][zet]*c[mu][f[zet]],{mu,0,i1}]

sub2[s_]:=Flatten[Table[D[w[i1][z],{z,k}]->D[cTwoStar[i1][zet],{zet,k}],{i1,1,m},{k,0,s-i1}]]

cTwoStarPoly[s_]:=wPolynomial[s]/.sub2[s]

firstCondition[s_]:=firstCondition[s]=Expand[rho[z]^s*(cOneStarPoly[s]-cPoly[s])]

secondCondition[s_]:=secondCondition[s]=Expand[f'[zet]^s*(cTwoStarPoly[s]-f'[zet]^s*(cPoly[s]/.z->f[zet]))]

v[s_,p1_]:=Floor[(1/p1)*(s-Sum[(i1+k)*e[s,i1,k],{i1,1,m},{k,0,s-i1}]-Sum[t*h[s,t],{t,p1+1,s}])]

nA[s_]:=Module[{counter,seq1,seq2},counter=0;
seq1=Apply[Sequence,Reverse[Flatten[Table[{e[s,i1,k],0,u[s,i1,k]},{i1,1,m},{k,0,s-i1}],1]]];
seq2=Apply[Sequence,Reverse[Table[{h[s,t],0,v[s,t]},{t,1,s}]]];
Do[If[(Sum[(i1+k)*e[s,i1,k],{i1,1,m},{k,0,s-i1}]+Sum[t*h[s,t],{t,1,s}])==s,(counter=counter+1;
monA[s,counter]=Product[D[c[i1][z],{z,k}]^e[s,i1,k],{i1,1,m},{k,0,s-i1}]*rho[z]^(s-Sum[h[s,t],{t,1,s}])*Product[D[rho[z],{z,t}]^h[s,t],{t,1,s}]),counter=counter],Evaluate[seq1],Evaluate[seq2]];counter]

printA[s_]:=Do[Print["monA[",s,", ",j,"] = ",monA[s,j]],{j,1,nA[s]}]

nB[s_]:=Module[{counter,seq1,seq2},counter=0;
seq1=Apply[Sequence,Reverse[Flatten[Table[{e[s,i1,k],0,u[s,i1,k]},{i1,1,m},{k,0,s-i1}],1]]];
seq2=Apply[Sequence,Reverse[Table[{h[s,t],0,v[s,t]},{t,1,s}]]];
Do[If[(Sum[(i1+k)*e[s,i1,k],{i1,1,m},{k,0,s-i1}]+Sum[t*h[s,t],{t,1,s}])==s,(counter=counter+1;
monB[s,counter]=Product[(D[c[i1][z],{z,k}]/.z->f[zet])^e[s,i1,k],{i1,1,m},{k,0,s-i1}]*f'[zet]^(2s-Sum[(t+1)*h[s,t],{t,1,s}])*Product[D[f[zet],{zet,t+1}]^h[s,t],{t,1,s}]),counter=counter],Evaluate[seq1],Evaluate[seq2]];counter]

printB[s_]:=Do[Print["monB[",s,", ",j,"] = ",monB[s,j]],{j,1,nB[s]}]

firstCoefficients[s_]:=Do[a[s,i]=Coefficient[firstCondition[s],monA[s,i]],{i,1,nA[s]}]

firstZeroCheck[s_]:=Expand[firstCondition[s]-Sum[a[s,i]*monA[s,i],{i,1,nA[s]}]]

secondCoefficients[s_]:=Do[b[s,j]=Coefficient[secondCondition[s],monB[s,j]],{j,1,nB[s]}]

secondZeroCheck[s_]:=Expand[secondCondition[s]-Sum[b[s,j]*monB[s,j],{j,1,nB[s]}]]

eqs[s_]:=Join[Table[a[s,i]==0,{i,1,nA[s]}],Table[b[s,j]==0,{j,1,nB[s]}]]

rules[s_]:=If[TrueQ[$VersionNumber<7.5],Flatten[Solve[eqs[s],Table[x[s,j],{j,1,nM[s]}]]],Flatten[Solve[eqs[s],Table[x[s,nM[s]+1-j],{j,1,nM[s]}]]]]

invariants[s_]:=Module[{expansion,counter},counter=0;
Print["   "];
Print["   Computation of invariants[",s,"]"];
Print["Number of Monic Monomials = ",nM[s]];
Print["Number of firstCondition Terms = ",nA[s]];
Print["Number of secondCondition Terms = ",nB[s]];
firstCondition[s];firstCoefficients[s];
Print["firstZeroCheck[",s,"] = ",firstZeroCheck[s]];
secondCondition[s];secondCoefficients[s];
Print["secondZeroCheck[",s,"] = ",secondZeroCheck[s]];expansion=Expand[(Sum[x[s,j]*monM[s,j],{j,1,nM[s]}])/.rules[s]];
Do[If[Length[Coefficient[expansion,x[s,j]]]≠0,(counter=counter+1;
inv[s,counter]=Coefficient[expansion,x[s,j]];
Print["inv[",s,", ",counter,"] = ",inv[s,counter]]),counter=counter],{j,1,nM[s]}];d[s]=counter;
Print["The vector space for weight ",s," has dimension d[",s,"] = ",d[s],"."]]

Input from Section 13.3

aFirstKind[m,1][z_]:=(1/Binomial[m+1,3])(w[2][z]-((m-1)/2)D[w[1][z],z]-((m-1)/(2m))w[1][z]^2)

B[h_,i_,j_][z_]:=0/;i≤-1

B[h_,0,j_][z_]:=1

B[h_,i_,j_][z_]:=Sum[D[B[h,i-1,k][z],z]-k(2h+k-1)aFirstKind[m,1][z]*B[h,i-2,k-1][z],{k,i-1,j-1}]/;i≥1

Ce[p_,q_,r_,mu_]:=(-1)^mu*Binomial[r,mu]*Binomial[2q+r-1,mu]/Binomial[2p+mu-1,mu]

A[p_,q_,r_,s_,t_][z_]:=Sum[Ce[p,q,r,t+k]*B[p,k,t+k][z]*B[q,s-k,r-t-k][z],{k,0,s}]

weight[iso_]:=Module[{h,seq,t1,t2,t3,t4,t5,t6,t7},t1=Expand[iso];
t2=If[Head[t1]===Plus,w[0][z]*t1[[1]],Expand[w[0][z]*t1]];
t3=Apply[List,t2];
seq={w[i_][z]->h[i,0,1],Power[w[i_][z],k_]->h[i,0,k],Derivative[j_][w[i_]][z]->h[i,j,1],Power[Derivative[j_][w[i_]][z],k_]->h[i,j,k]};
t4=t3/.seq;
t5=Cases[t4,h[i_,j_,k_]];
t6=t5/.h[i_,j_,k_]->(i+j)k;
t7=Apply[Plus,t6]]

Com[r_,P_,Q_]:=Module[{p,q},p=weight[P];q=weight[Q];
Sum[A[p,q,r,s,t][z]*D[P,{z,t}]*D[Q,{z,r-s-t}],{s,0,r},{t,0,r-s}]]

Verifications for Section 12.2    
(where m = 5 and n = 1)

invariants[3]

n[3,1] = inv[3,1];

invariants[4]

n[4,1] = inv[4,1];

invariants[5]

n[5,1] = inv[5,1];

invariants[6]

n[6,1] = n[3,1]^2;

Expand[ inv[6,1] - n[6,1] ]

invariants[7]

n[7,1] = n[3,1]*n[4,1];

Expand[ inv[7,1] - n[7,1] ]

invariants[8]

n[8,1] = n[3,1]*n[5,1];

n[8,2] = n[4,1]^2;

n[8,3] = Com[2, n[3,1], n[3,1]];

n[8,4] = Com[1, n[3,1], n[4,1]];

Do[ expr[8,i]=(inv[8,i]-Sum[c[8,i,j]*n[8,j],{j,1,d[8]}]),{i,1,d[8]}]

nM[8]

Do[y[8,i,k] = Coefficient[ expr[8,i], monM[8,k]],{k,1,101,10}, {i,1,d[8]}]

sol[8,i_] := Solve[ Table[y[8,i,k] == 0, {k,1,101,10}], Table[c[8,i,j], {j,1,d[8]}] ]

sol[8,1]

Expand[ inv[8,1] - (1/2)n[8,3] ]

sol[8,2]

Expand[ inv[8,2] - n[8,2] ]

sol[8,3]

Expand[ inv[8,3] - ((1/2)n[8,3] +n[8,4]) ]

sol[8,4]

Expand[ inv[8,4] - (n[8,1]+(1/7)n[8,3]+(1/2)n[8,4]) ]

invariants[9]

n[9,1] = n[3,1]^3;

n[9,2] = n[4,1]*n[5,1];

n[9,3] = Com[2, n[3,1], n[4,1]];

n[9,4] = Com[1, n[3,1], n[5,1]];

Do[ expr[9,i]=(inv[9,i]-Sum[c[9,i,j]*n[9,j],{j,1,d[9]}]),{i,1,d[9]}]

nM[9]

Do[y[9,i,k] = Coefficient[ expr[9,i], monM[9,k]],{k,1,101,10}, {i,1,d[9]}]

sol[9,i_] := Solve[ Table[y[9,i,k] == 0, {k,1,101,10}], Table[c[9,i,j], {j,1,d[9]}] ]

sol[9,1]

Expand[ inv[9,1] - n[9,1] ]

sol[9,2]

Expand[ inv[9,2] - n[9,3] ]

sol[9,3]

Expand[ inv[9,3] - n[9,2] ]

sol[9,4]

Expand[ inv[9,4] - ((1/2)n[9,3]+n[9,4]) ]

invariants[10]

n[10,1] = n[3,1]^2*n[4,1];

n[10,2] = n[5,1]^2;

n[10,3] = Com[4, n[3,1], n[3,1]];

n[10,4] = Com[3, n[3,1], n[4,1]];

n[10,5] = Com[2, n[3,1], n[5,1]];

n[10,6] = Com[2, n[4,1], n[4,1]];

n[10,7] = Com[1, n[4,1], n[5,1]];

Do[ expr[10,i]=(inv[10,i]-Sum[c[10,i,j]*n[10,j],{j,1,d[10]}]),{i,1,d[10]}]

nM[10]

Do[y[10,i,k] = Coefficient[ expr[10,i], monM[10,k]],{k,1,101,10}, {i,1,d[10]}]

sol[10,i_] := Solve[ Table[y[10,i,k] == 0, {k,1,101,10}], Table[c[10,i,j], {j,1,d[10]}] ]

sol[10,1]

Expand[ inv[10,1] - (1/2)n[10,3] ]

sol[10,2]

Expand[ inv[10,2] - n[10,1] ]

sol[10,3]

Expand[ inv[10,3] - (1/2)n[10,6] ]

sol[10,4]

Expand[ inv[10,4] - ((1/2)n[10,3]+n[10,4]) ]

sol[10,5]

Expand[ inv[10,5] - n[10,2] ]

sol[10,6]

Expand[ inv[10,6] -((1/4)n[10,6]+n[10,7]) ]

sol[10,7]

Expand[ inv[10,7] - ((1/7)n[10,3]+(1/2)n[10,4]+n[10,5]) ]

MaxMemoryUsed[]

DateList[]

invariants[11]

DateList[]

MaxMemoryUsed[]

n[11,1] = n[3,1]^2*n[5,1];

n[11,2] = n[3,1]*n[4,1]^2;

n[11,3] = Com[4, n[3,1], n[4,1]];

n[11,4] = Com[3, n[3,1], n[5,1]];

n[11,5] = Com[2, n[3,1], n[3,1]^2];

n[11,6] = Com[2, n[4,1], n[5,1]];

n[11,7] = Com[1, n[3,1], n[3,1]*n[4,1]];

Do[ expr[11,i]=(inv[11,i]-Sum[c[11,i,j]*n[11,j],{j,1,d[11]}]),{i,1,d[11]}]

nM[11]

Do[y[11,i,k] = Coefficient[ expr[11,i], monM[11,k]],{k,1,701,20}, {i,1,d[11]}]

sol[11,i_] := Solve[ Table[y[11,i,k] == 0, {k,1,701,20}], Table[c[11,i,j], {j,1,d[11]}] ]

sol[11,1]

Expand[ inv[11,1] - (7/40)n[11,5] ]

sol[11,2]

Expand[ inv[11,2] - n[11,2] ]

sol[11,3]

Expand[ inv[11,3] - ((7/40)n[11,5]+n[11,7]) ]

sol[11,4]

Expand[ inv[11,4] - n[11,3] ]

sol[11,5]

Expand[ inv[11,5] - (n[11,1]+(1/20)n[11,5]+(1/2)n[11,7]) ]

sol[11,6]

Expand[ inv[11,6] - n[11,6] ]

sol[11,7]

Expand[ inv[11,7] - ((1/2)n[11,3]+n[11,4]) ]

MaxMemoryUsed[]

DateList[]

invariants[12]

DateList[]

MaxMemoryUsed[]

n[12,1] = n[3,1]^4;

n[12,2] = n[4,1]^3;

n[12,3] = n[3,1]*n[4,1]*n[5,1];

n[12,4] = Com[6, n[3,1], n[3,1]];

n[12,5] = Com[5, n[3,1], n[4,1]];

n[12,6] = Com[4, n[3,1], n[5,1]];

n[12,7] = Com[4, n[4,1], n[4,1]];

n[12,8] = Com[3, n[3,1], n[3,1]^2];

n[12,9] = Com[3, n[4,1], n[5,1]];

n[12,10] = Com[2, n[3,1], n[3,1]*n[4,1]];

n[12,11] = Com[2, n[4,1], n[3,1]^2];

n[12,12] = Com[2, n[5,1], n[5,1]];

n[12,13] = Com[1, n[3,1], n[3,1]*n[5,1]];

n[12,14] = Com[1, n[3,1], n[4,1]^2];

Do[ expr[12,i]=(inv[12,i]-Sum[c[12,i,j]*n[12,j],{j,1,d[12]}]),{i,1,d[12]}]

nM[12]

Do[y[12,i,k] = Coefficient[ expr[12,i], monM[12,k]],{k,1,701,20}, {i,1,d[12]}]

sol[12,i_] := Solve[ Table[y[12,i,k] == 0, {k,1,701,20}], Table[c[12,i,j], {j,1,d[12]}] ]

Expand[ inv[12,1] - n[12,1] ]

Expand[ inv[12,2] - (-2/9)n[12,8] ]

Expand[ inv[12,3] - (1/2)n[12,4] ]

Expand[ inv[12,4] - ((13/66)n[12,10]+(-1/11)n[12,11]) ]

Expand[ inv[12,5] - n[12,2] ]

Expand[ inv[12,6] - ((13/66)n[12,10]+(-1/11)n[12,11]+(1/2)n[12,14]) ]

Expand[ inv[12,7] - ((-2/9)n[12,8]+(-2/11)n[12,10]+(6/11)n[12,11]) ]

Expand[ inv[12,8] - (1/2)n[12,7] ]

Expand[ inv[12,9] - ((-1/2)n[12,4]+n[12,5]) ]

Expand[ inv[12,10] - (n[12,3]+(13/231)n[12,10]+(-2/77)n[12,11]+(1/4)n[12,14]) ]

Expand[ inv[12,11] - ((-4/63)n[12,8]+(-1/11)n[12,10]+(3/11)n[12,11]+n[12,13]) ]

Expand[ inv[12,12] - (1/2)n[12,12] ]

Expand[ inv[12,13] - ((1/4)n[12,7]+n[12,9]) ]

Expand[ inv[12,14] - ((1/7)n[12,4]+(1/2)n[12,5]+n[12,6]) ]