Complete details for Section 4.8 
based on Sections 13.1 and 13.3
(with m = 3 and n = 1)

$VersionNumber

Input from Section 13.1

Subsection 13.1.1

m=3;

u[s_,p1_,r_]:=Floor[(1/(p1+r))*(s-Sum[(p1+k)*e[s,p1,k],{k,r+1,s-p1}]-Sum[(i1+k)*e[s,i1,k],{i1,p1+1,m},{k,0,s-i1}])]

nM[s_]:=Module[{counter,seq},counter=0;
seq=Apply[Sequence,Reverse[Flatten[Table[{e[s,i1,k],0,u[s,i1,k]},{i1,1,m},{k,0,s-i1}],1]]];
Do[If[(Sum[(i1+k)*e[s,i1,k],{i1,1,m},{k,0,s-i1}])==s,(counter=counter+1;
monM[s,counter]=Product[D[w[i1][z],{z,k}]^e[s,i1,k],{i1,1,m},{k,0,s-i1}]),counter=counter],Evaluate[seq]];counter]

printM[s_]:=Do[Print["monM[",s,",",j,"] = ",monM[s,j]],{j,1,nM[s]}]

printM[4]

Subsection 13.1.2

wPolynomial[s_]:=Sum[x[s,j]*monM[s,j],{j,1,nM[s]}]

sub[s_]:=Flatten[Table[D[w[i1][z],{z,k}]->D[c[i1][z],{z,k}],{i1,1,m},{k,0,s-i1}]]

cPoly[s_]:=wPolynomial[s]/.sub[s]

c[0][z_]=1;

cOneStar[i1_][z_]:=Sum[Binomial[m-j1,i1-j1]*(D[rho[z],{z,i1-j1}]/rho[z])*c[j1][z],{j1,0,i1}]

sub1[s_]:=Flatten[Table[D[w[i1][z],{z,k}]->D[cOneStar[i1][z],{z,k}],{i1,1,m},{k,0,s-i1}]]

cOneStarPoly[s_]:=wPolynomial[s]/.sub1[s]

alpha[0,j_][zet_]=1;

alpha[i_,j_][zet_]:=Sum[D[alpha[i-1,k][zet],zet]-(i-1+k)(f''[zet]/f'[zet])alpha[i-1,k][zet],{k,1,j}]/;i≥1

cTwoStar[i1_][zet_]:=Sum[f'[zet]^mu*alpha[i1-mu,m-i1][zet]*c[mu][f[zet]],{mu,0,i1}]

sub2[s_]:=Flatten[Table[D[w[i1][z],{z,k}]->D[cTwoStar[i1][zet],{zet,k}],{i1,1,m},{k,0,s-i1}]]

cTwoStarPoly[s_]:=wPolynomial[s]/.sub2[s]

firstCondition[s_]:=firstCondition[s]=Expand[rho[z]^s*(cOneStarPoly[s]-cPoly[s])]

secondCondition[s_]:=secondCondition[s]=Expand[f'[zet]^s*(cTwoStarPoly[s]-f'[zet]^s*(cPoly[s]/.z->f[zet]))]

Subsection 13.1.3

v[s_,p1_]:=Floor[(1/p1)*(s-Sum[(i1+k)*e[s,i1,k],{i1,1,m},{k,0,s-i1}]-Sum[t*h[s,t],{t,p1+1,s}])]

nA[s_]:=Module[{counter,seq1,seq2},counter=0;
seq1=Apply[Sequence,Reverse[Flatten[Table[{e[s,i1,k],0,u[s,i1,k]},{i1,1,m},{k,0,s-i1}],1]]];
seq2=Apply[Sequence,Reverse[Table[{h[s,t],0,v[s,t]},{t,1,s}]]];
Do[If[(Sum[(i1+k)*e[s,i1,k],{i1,1,m},{k,0,s-i1}]+Sum[t*h[s,t],{t,1,s}])==s,(counter=counter+1;
monA[s,counter]=Product[D[c[i1][z],{z,k}]^e[s,i1,k],{i1,1,m},{k,0,s-i1}]*rho[z]^(s-Sum[h[s,t],{t,1,s}])*Product[D[rho[z],{z,t}]^h[s,t],{t,1,s}]),counter=counter],Evaluate[seq1],Evaluate[seq2]];counter]

printA[s_]:=Do[Print["monA[",s,", ",j,"] = ",monA[s,j]],{j,1,nA[s]}]

printA[2]

Subsection 13.1.4

nB[s_]:=Module[{counter,seq1,seq2},counter=0;
seq1=Apply[Sequence,Reverse[Flatten[Table[{e[s,i1,k],0,u[s,i1,k]},{i1,1,m},{k,0,s-i1}],1]]];
seq2=Apply[Sequence,Reverse[Table[{h[s,t],0,v[s,t]},{t,1,s}]]];
Do[If[(Sum[(i1+k)*e[s,i1,k],{i1,1,m},{k,0,s-i1}]+Sum[t*h[s,t],{t,1,s}])==s,(counter=counter+1;
monB[s,counter]=Product[(D[c[i1][z],{z,k}]/.z->f[zet])^e[s,i1,k],{i1,1,m},{k,0,s-i1}]*f'[zet]^(2s-Sum[(t+1)*h[s,t],{t,1,s}])*Product[D[f[zet],{zet,t+1}]^h[s,t],{t,1,s}]),counter=counter],Evaluate[seq1],Evaluate[seq2]];counter]

printB[s_]:=Do[Print["monB[",s,", ",j,"] = ",monB[s,j]],{j,1,nB[s]}]

printB[2]

Subsection 13.1.5

firstCoefficients[s_]:=Do[a[s,i]=Coefficient[firstCondition[s],monA[s,i]],{i,1,nA[s]}]

firstZeroCheck[s_]:=Expand[firstCondition[s]-Sum[a[s,i]*monA[s,i],{i,1,nA[s]}]]

secondCoefficients[s_]:=Do[b[s,j]=Coefficient[secondCondition[s],monB[s,j]],{j,1,nB[s]}]

secondZeroCheck[s_]:=Expand[secondCondition[s]-Sum[b[s,j]*monB[s,j],{j,1,nB[s]}]]

eqs[s_]:=Join[Table[a[s,i]==0,{i,1,nA[s]}],Table[b[s,j]==0,{j,1,nB[s]}]]

rules[s_]:=If[TrueQ[$VersionNumber<7.5],Flatten[Solve[eqs[s],Table[x[s,j],{j,1,nM[s]}]]],Flatten[Solve[eqs[s],Table[x[s,nM[s]+1-j],{j,1,nM[s]}]]]]

invariants[s_]:=Module[{expansion,counter},counter=0;Print["   "];
Print["   Computation of invariants[",s,"]"];
Print["Number of Monic Monomials = ",nM[s]];
Print["Number of firstCondition Terms = ",nA[s]];
Print["Number of secondCondition Terms = ",nB[s]];
firstCondition[s];firstCoefficients[s];
Print["firstZeroCheck[",s,"] = ",firstZeroCheck[s]];
secondCondition[s];secondCoefficients[s];
Print["secondZeroCheck[",s,"] = ",secondZeroCheck[s]];expansion=Expand[(Sum[x[s,j]*monM[s,j],{j,1,nM[s]}])/.rules[s]];
Do[If[Length[Coefficient[expansion,x[s,j]]]≠0,(counter=counter+1;
inv[s,counter]=Coefficient[expansion,x[s,j]];
Print["inv[",s,", ",counter,"] = ",inv[s,counter]]),counter=counter],{j,1,nM[s]}];d[s]=counter;
Print["The vector space for weight ",s," has dimension d[",s,"] = ",d[s],"."]]

DateList[]

Do[invariants[s],{s,{2,4,5,7}}]

DateList[]

Do[invariants[s],{s,{3,6,8,9,10,11,12,13}}]

DateList[]

DateString[{2013,9,14,21,25,14.4742224`8.913170192357748}]

DateString[{2013,9,12,22,27,25.5540333`9.160034377367776}]

MemoryInUse[]

MaxMemoryUsed[]

Input from Section 13.3

weight[iso_]:=Module[{h,seq,t1,t2,t3,t4,t5,t6,t7},t1=Expand[iso];
t2=If[Head[t1]===Plus,w[0][z]*t1[[1]],Expand[w[0][z]*t1]];
t3=Apply[List,t2];
seq={w[i_][z]->h[i,0,1],Power[w[i_][z],k_]->h[i,0,k],Derivative[j_][w[i_]][z]->h[i,j,1],Power[Derivative[j_][w[i_]][z],k_]->h[i,j,k]};
t4=t3/.seq;
t5=Cases[t4,h[i_,j_,k_]];
t6=t5/.h[i_,j_,k_]->(i+j)k;
t7=Apply[Plus,t6]]

aFirstKind[m,1][z_]:=(1/Binomial[m+1,3])(w[2][z]-((m-1)/2)D[w[1][z],z]-((m-1)/(2m))w[1][z]^2)

B[h_,i_,j_][z_]:=0/;i≤-1

B[h_,0,j_][z_]:=1

B[h_,i_,j_][z_]:=Sum[D[B[h,i-1,k][z],z]-k(2h+k-1)aFirstKind[m,1][z]*B[h,i-2,k-1][z],{k,i-1,j-1}]/;i≥1

Ce[p_,q_,r_,mu_]:=(-1)^mu*Binomial[r,mu]*Binomial[2q+r-1,mu]/Binomial[2p+mu-1,mu]

A[p_,q_,r_,s_,t_][z_]:=Sum[Ce[p,q,r,t+k]*B[p,k,t+k][z]*B[q,s-k,r-t-k][z],{k,0,s}]

Com[r_,P_,Q_]:=Module[{p,q},p=weight[P];q=weight[Q];
Sum[A[p,q,r,s,t][z]*D[P,{z,t}]*D[Q,{z,r-s-t}],{s,0,r},{t,0,r-s}]]

Computations for Section 4.8

invariants[3]

L[3,1]:=inv[3,1];

L[6,1]:=L[3,1]^2;

L[8,1]:=Com[2,L[3,1],L[3,1]];

L[9,1]:=L[3,1]^3;

L[10,1]:=Com[4,L[3,1],L[3,1]];

L[11,1]:=Com[2,L[3,1],L[3,1]^2];

L[12,1]:=L[3,1]^4;

L[12,2]:=Com[6,L[3,1],L[3,1]];

L[12,3]:=Com[3,L[3,1],L[3,1]^2];

L[13,1]:=Com[4,L[3,1],L[3,1]^2];

Expand[  inv[6,1] - L[6,1] ]

Expand[  inv[8,1] - (1/2)L[8,1] ]

Expand[ inv[9,1] - L[9,1] ]

Expand[ inv[10,1] - (1/2)L[10,1] ]

Expand[ inv[11,1] - (7/40)L[11,1] ]

Expand[ inv[12,1] - L[12,1] ]

Expand[ inv[12,2] - (-2/9)L[12,3] ]

Expand[ inv[12,3] - (1/2)L[12,2] ]

Expand[ inv[13,1] - (6/77)L[13,1] ]

System Information about PC

System Information report written at: 09/14/13 23:37:02
System Name: OWNER-PC
[System Summary]
Item Value
OS Name Microsoft Windows 7 Professional
Version 6.1.7601 Service Pack 1 Build 7601
Other OS Description Not Available
OS Manufacturer Microsoft Corporation
System Name OWNER-PC
System Manufacturer HP-Pavilion
System Model NY550AA-ABA p6240f
System Type x64-based PC
Processor Intel(R) Core(TM)2 Quad CPU Q8300 @ 2.50GHz, 2499 Mhz, 4 Core(s), 4 Logical Processo
r(s)
BIOS Version/Date American Megatrends Inc. 5.11, 9/29/2009
SMBIOS Version 2.5
Windows Directory C:\Windows
System Directory C:\Windows\system32
Boot Device \Device\HarddiskVolume1
Locale United States
Hardware Abstraction Layer Version = "6.1.7601.17514"
User Name Owner-PC\Owner
Time Zone Eastern Daylight Time
Installed Physical Memory (RAM) 8.00 GB
Total Physical Memory 7.97 GB
Available Physical Memory 4.24 GB
Total Virtual Memory 15.9 GB
Available Virtual Memory 11.6 GB
Page File Space 7.97 GB
Page File C:\pagefile.sys