The following computation checks that: for any m >= 1 and any n >= 3, the expression defined by (27.46) for k = 3 is a relative invariant for the equations (21.1)

Similar checks can be made for k = 4, k = 5, and etc.

A[i1_, i2_, i3_, j1_, j2_, j3_]  :=  
      Binomial[m - j1, i1 - j1]*Binomial[m - j2, i2 - j2]*
        Binomial[m - j3, i3 - j3]*D[ rho[z], {z, i1 - j1}]*
        D[rho[z], {z, i2 - j2}]*D[rho[z], {z, i3 - j3}]/rho[z]^3

cStar[i1_, i2_, i3_]  :=  
      Sum[ A[i1, i2, i3, j1, j2, j3]*c[j1, j2, j3],  {j1, 0, i1}, {j2, 0, 
          i2}, {j3, 0, i3}]

c[i2_, i1_, i3_]  :=  c[i1, i2, i3]  /;   i1 < i2

c[i1_, i3_, i2_]  :=  c[i1, i2, i3]   /;   i2  <  i3

c[0, 0, 0]  =  1

cStar[1, 1, 1]

cStar[0, 1, 1]

B3Star  =  
      cStar[1, 1, 1]  -  3  cStar[0, 0, 1]*cStar[0, 1, 1] + 
          2*cStar[0, 0, 1]^3   // Expand

B3  =  
      c[1, 1, 1]  - 3  c[0, 0, 1]*c[0, 1, 1] + 2  c[0, 0, 1]^3

expr  =  (B3Star  -  B3)  //  Expand

expr  /.  m -> 1    // Expand

alpha[0, j_]  =  1

alpha[1, j_]  =  -j*(j + 1) f2/(2  f1)

B[i1_, i2_, i3_, j1_, j2_, j3_]  :=  
      f1^(j1 + j2 + j3)*alpha[i1 - j1, m - i1]*alpha[i2 - j2, m - i2]*
        alpha[i3 - j3, m - i3]

cDoubleStar[i1_, i2_, i3_]  :=  
      Sum[ B[i1, i2, i3, j1, j2, j3]*c[j1, j2, j3], {j1, 0, i1}, {j2, 0, 
          i2}, {j3, 0, i3}]

cDoubleStar[1, 0, 1]    //  Expand

cDoubleStar[0, 1, 1]   // Expand

B3DoubleStar  =  
      cDoubleStar[1, 1, 1]  -  
          3*cDoubleStar[0, 0, 1]*cDoubleStar[0, 1, 1]  +  
          2*cDoubleStar[0, 0, 1]^3  //  Expand

B3DoubleStar   -   B3*f1^3   // Expand