$Version

Mathematica Notebook for Chapter 18

Copy-and-paste from the Latex Document for pages 178--182 of the monograph 
          “Constructions of Relative Invariants
             for Ordinary Differential Equations”
yields this Notebook for the verification of Theorem 18.7 on page 177
and Formula (18.24) on page 180.

Ce[m_,0][z_]:=1

alpha[0,j_][zeta_]:=1

alpha[i_,j_][zeta_]:=(Sum[alpha[i-1,k]'[zeta]-(i-1+k)(f''[zeta]/f'[zeta])*alpha[i-1,k][zeta],{k,1,j}])/;i≥1

beta[m_,r_,s_][zeta_]:=(Product[(m-s-k+1),{k,1,r}]/Product[(s+k),{k,1,r}])*alpha[r,s][zeta]

CeSS[m_,i_][zeta_]:=Sum[beta[m,i-j,m-i][zeta]*(f'[zeta])^j*Ce[m,j][f[zeta]],{j,0,i}]

F[0][z_]:=1

F[1][z_]:=-Ce[m,1][z]

F[i_][z_]:=F[i-1]'[z]+F[1][z]*F[i-1][z]/;i≥2

G[i_][z_]:=Sum[Binomial[i,j]*F[i-j][z]*Ce[m,j][z],{j,0,i}]

FSS[0][zeta_]:=1

FSS[1][zeta_]:=-CeSS[m,1][zeta]

FSS[i_][zeta_]:=FSS[i-1]'[zeta]+FSS[1][zeta]*FSS[i-1][zeta]/;i≥2

GSS[i_][zeta_]:=Sum[Binomial[i,j]*FSS[i-j][zeta]*CeSS[m,j][zeta],{j,0,i}]

Theta[3][z_]:=(G[3][z]-(3/2)G[2]'[z])

ThetaSS[3][zeta_]:=(GSS[3][zeta]-(3/2)GSS[2]'[zeta])

FullSimplify[ThetaSS[3][zeta]-f'[zeta]^3*Theta[3][f[zeta]]]

Theta[4][z_]:=(G[4][z]-2G[3]'[z]+(6/5)G[2]''[z]-(3/5)((5m+7)/(m+1))G[2][z]^2)

ThetaSS[4][zeta_]:=(GSS[4][zeta]-2GSS[3]'[zeta]+(6/5)GSS[2]''[zeta]-(3/5)((5m+7)/(m+1))GSS[2][zeta]^2)

FullSimplify[ThetaSS[4][zeta]-f'[zeta]^4*Theta[4][f[zeta]]]

Theta[5][z_]:=(G[5][z]-(5/2)G[4]'[z]+(15/7)G[3]''[z]-(5/7)G[2]'''[z]-(10/7)((7m+13)/(m+1))G[2][z]*Theta[3][z])

ThetaSS[5][zeta_]:=(GSS[5][zeta]-(5/2)GSS[4]'[zeta]+(15/7)GSS[3]''[zeta]-(5/7)GSS[2]'''[zeta]-(10/7)((7m+13)/(m+1))GSS[2][zeta]*ThetaSS[3][zeta])

FullSimplify[ThetaSS[5][zeta]-f'[zeta]^5*Theta[5][f[zeta]]]

Theta[6][z_]:=(G[6][z]-3G[5]'[z]+(10/3)G[4]''[z]-(5/3)G[3]'''[z]+(5/14)G[2]''''[z]+(30/7)G[2][z]^3*((7m^2+28m+25)/(m+1)^2)+(5/14)((7m+8)/(m+1))G[2]'[z]^2-5((3m+7)/(m+1))G[2][z]*(G[4][z]-2G[3]'[z]+(2/7)((14m+31)/(3m+7))G[2]''[z]))

ThetaSS[6][zeta_]:=(GSS[6][zeta]-3GSS[5]'[zeta]+(10/3)GSS[4]''[zeta]-(5/3)GSS[3]'''[zeta]+(5/14)GSS[2]''''[zeta]+(30/7)GSS[2][zeta]^3*((7m^2+28m+25)/(m+1)^2)+(5/14)((7m+8)/(m+1))GSS[2]'[zeta]^2-5((3m+7)/(m+1))GSS[2][zeta]*(GSS[4][zeta]-2GSS[3]'[zeta]+(2/7)((14m+31)/(3m+7))GSS[2]''[zeta]))

FullSimplify[ThetaSS[6][zeta]-f'[zeta]^6*Theta[6][f[zeta]]]

Theta[7][z_]:=(G[7][z]-(7/2)G[6]'[z]+(105/22)G[5]''[z]-(35/11)G[4]'''[z]+(35/33)G[3]''''[z]-(7/44)G[2]'''''[z]-(7/11)(G[2][z]/(m+1))*((3/2)(11m+31)(2G[5][z]-5G[4]'[z])+5(15m+41)G[3]''[z]-15(2m+5)G[2]'''[z])-(7/11)((3m+4)/(m+1))*(3G[2]''[z](G[3][z]+G[2]'[z])-5G[2]'[z]*G[3]'[z])+G[2][z]^2*Theta[3][z]*((1155m^2+6048m+6909)/(11(m+1)^2)))

ThetaSS[7][zeta_]:=(GSS[7][zeta]-(7/2)GSS[6]'[zeta]+(105/22)GSS[5]''[zeta]-(35/11)GSS[4]'''[zeta]+(35/33)GSS[3]''''[zeta]-(7/44)GSS[2]'''''[zeta]-(7/11)(GSS[2][zeta]/(m+1))*((3/2)(11m+31)(2GSS[5][zeta]-5GSS[4]'[zeta])+5(15m+41)GSS[3]''[zeta]-15(2m+5)GSS[2]'''[zeta])-(7/11)((3m+4)/(m+1))(3GSS[2]''[zeta]*(GSS[3][zeta]+GSS[2]'[zeta])-5GSS[2]'[zeta]*GSS[3]'[zeta])+GSS[2][zeta]^2*ThetaSS[3][zeta]*(21(55m^2+288m+329)/(11(m+1)^2)))

FullSimplify[ThetaSS[7][zeta]-f'[zeta]^7*Theta[7][f[zeta]]]

Since the last five evaluations are zero, this establishes that Theorem 18.7 on page 177 is valid.

To verify Formula (18.24) on page  10, we continue with the input of pages 178--182.

Ce[m_,i_][z_]=W[i][z]

a[m_,1][z_]:=(1/Binomial[m+1,3])(w[2][z]-((m-1)/2)w[1]'[z]-((m-1)/(2m))w[1][z]^2)

d[m_,1][z_]:=(1/(m(m-1)))w[1][z]

K[m_,1,i_,j_][z_]:=0/;i≤-1

K[m_,1,0,j_][z_]:=1

K[m_,1,i_,j_][z_]:=(Sum[(D[K[m,1,i-1,k][z],z]-(m-1)*d[m,1][z]*K[m,1,i-1,k][z]+(m+2-i-k)(2-i-k)a[m,1][z]*K[m,1,i-2,k][z]),{k,j+1,m}])/;i≥1

w[0][z_]=1;X[k_][z_]:=w[k][z]

L[m_,1,i_][z_]:=Sum[K[m,1,i-j,j][z]*X[j][z],{j,0,i}]

M[m_,1,e1_,i_][z_]:=FunctionExpand[Binomial[m-i,e1-i]]*Product[(e1-r),{r,1,e1-i}]*L[m,1,i][z]

A[e1_,i_]:=-1/(e1+i-1)/;i≥1

B[e1_,i_]:=(e1-i)/(e1+i-2)/;i≥1

inv[m_,1,e1_,0][z_]:=0

inv[m_,1,e1_,1][z_]:=0

inv[m_,1,e1_,i_][z_]:=(M[m,1,e1,i][z]+A[e1,i-1]*D[inv[m,1,e1,i-1][z],z]+B[e1,i-1]*a[m,1][z]*inv[m,1,e1,i-2][z])/;i≥2

basicInv[m_,1,e1_][z_]:=inv[m,1,e1,e1][z]

binomial[m_,i_] :=Product[m-k,{k,0,i-1}]/i!

w[i_][z_]:=binomial[m,i]*W[i][z]

FullSimplify[basicInv[m,1,3][z]-binomial[m,3]*Theta[3][z]]

FullSimplify[basicInv[m,1,4][z]-binomial[m,4]*Theta[4][z]]

FullSimplify[basicInv[m,1,5][z]-binomial[m,5]*Theta[5][z]]

FullSimplify[basicInv[m,1,6][z]-binomial[m,6]*Theta[6][z]]

FullSimplify[basicInv[m,1,7][z]-binomial[m,7]*Theta[7][z]]

Since the last five evaluations are zero, this establishes the validity of (18.24) on page 180.